From news@valhalla.stormking.com Tue Feb  7 04:08:23 1995
Received: by valhalla.stormking.com with UUCP id AA17248
  (5.65c/IDA-1.5 for cbx.rec.games.corewar); Sat, 11 Feb 1995 18:33:56 -0500
From: pk6811s@acad.drake.edu
Newsgroups: rec.games.corewar
Subject: Re: djn -3,<1499, cmp-scanning
Date: 7 Feb 95 10:08:23 CST
Organization: Drake University, Des Moines, Iowa
Lines: 76
Distribution: world
Message-Id: <1995Feb7.100823@acad.drake.edu>
References: <1995Feb6.170908.1817@rhodes>
Nntp-Posting-Host: acad.drake.edu
Apparently-To: cbx.rec.games.corewar@valhalla.stormking.com

In article <1995Feb6.170908.1817@rhodes>, graham@harlie.mathcs.rhodes.edu (Randy Graham) writes:
> I've been looking at some code from code for warriors and feel like I
> am starting to get a handle on what is happening with many of them,
> but I still have questions. I have been looking at Rave and Coreclear
> (don't think that's its real name, but its by P.Kline I believe).
> Anyway, both of them have chunks like the following:
> (actually, this is the complete code I have for CoreClear)
> 
> 	add	off,	1
> loc	cmp	1,	50
> 	slt	#20,	-1
> 	djn	-3,	<1499
> 	mov	j,	@loc
> dec	mov	s,	<loc
> 	add	new,	@dec
> 	jmz	-6,	#0
> 	mov	s,	7+381
> 	add	#381,	0
> j	djn	@-1,	#6900
> s	spl	0
> new	mov	-49,	<-48
> off	dat	<-98,	<-98
> 

Um... don't remember this one.

Anyway the DJN XX,<YY code is called djn-stream or djn-train.  If you
set one up and watch it you will observe that it decrements the b-operand
of core locations in the order YY, YY-1, YY-2, YY-3, etc. - a fairly 
powerful thing to do.  It doesn't cost you anything and you might overrun
your opponent this way.

Next, imagine what happens when the djn-stream overruns your own code.
All the instructions after the djn have their b-operands decremented
once.  In particular the 'jmz -6, #0' is changed to 'jmz -6, #-1' so
it will fall through the next time it is executed.  The program starts
bombing with 'spl 0' at 381 increments - about 6900 bombs worth, which
should incapacitate any remaining code.  Actually the 381 increment
is designed to overrun 3- and 9-point spirals.  After that it starts
the standard core-clear.

A nice program, little bit long and could be optimized under '94 rules
but interesting.

Here is a partially-documented version of Creampuff - an experimental
spl/jmp bombing cmp-scanner:

;redcode
;name Creampuff II
;kill Creampuff
;author P. Kline
;strategy 12-line, spl-jmp bombing cmp-scanner
;strategy no decoy, partial gate, and using imp-killing step

half    equ 59
full    equ (half+half)

attack  add reset,@scanptr               ; found something -> attack at a-pointer
        mov bjmp,@scan                   ; jmp half of the bomb
scanptr mov bspl,<scan                   ; spl half "  "  "
next    add incr,scan                    ; increment scanning pointers
scan    cmp half+full,full+full          ; compare locations
        slt #incr-attack+half+1,@scanptr ; don't bomb self
        djn next,<-20                    ; djn-stream, countdown
        jmz attack,0                     ; loop until overrun by djn-stream
bspl    spl 0,<2667                      ;      (mine or yours)
reset   mov 0-half,<1-half               ; core-clear
bjmp    jmp -1,<1-half+2667              ; 
incr    dat #full,#full                  ; scanning increment
        end scan                         ; start right off scanning :-)

Note the @scanptr references which work fine even when incremented or 
decremented.

Paul Kline
pk6811s@acad.drake.edu